ESP8266 avec BME280 utilisant Arduino IDE (pression, température, humidité)

ESP8266 avec BME280 utilisant Arduino IDE (pression, température, humidité)

Ce guide montre comment utiliser le module de capteur BME280 avec l’ESP8266 pour lire la pression, la température, l’humidité et estimer l’altitude à l’aide de l’IDE Arduino. Le capteur BME280 utilise le protocole de communication I2C ou SPI pour échanger des données avec un microcontrôleur.

ESP8266 avec BME280 utilisant Arduino IDE (pression, température, humidité)

Nous allons vous montrer comment câbler le capteur à l’ESP8266, installer les bibliothèques requises et écrire un croquis simple qui affiche les lectures du capteur. Nous allons également créer un exemple de serveur Web pour afficher les dernières lectures de pression, de température et d’humidité.

Avant de poursuivre ce didacticiel, vous devez avoir installé le module complémentaire ESP8266 dans votre IDE Arduino.

Vous aimerez peut-être aussi lire d’autres guides BME280 :

Présentation du module de capteur BME280

le Capteur BME280 module lit la pression barométrique, la température et l’humidité. Étant donné que la pression change avec l’altitude, vous pouvez également estimer l’altitude. Il existe plusieurs versions de ce module capteur. Nous utilisons le module illustré dans la figure ci-dessous.

Le module BME280 Sensor I2C lit la pression, la température et l'humidité

Ce capteur communique à l’aide du protocole de communication I2C, le câblage est donc très simple. Vous pouvez utiliser les broches ESP8266 I2C par défaut comme indiqué dans le tableau suivant :

BME280 ESP8266
vin 3.3V
Terre Terre
SCL GPIO 5
SDA GPIO 4

Il existe d’autres versions de ce capteur qui peuvent utiliser les protocoles de communication SPI ou I2C, comme le module illustré dans la figure suivante :

Protocoles de communication SPI ou I2C du module de capteur BME280

Si vous utilisez l’un de ces capteurs, pour utiliser le protocole de communication I2C, utilisez les broches suivantes :

BME280 ESP8266
SCK (broche SCL) GPIO 5
SDI (broche SDA) GPIO 4

Si vous utilisez le protocole de communication SPI, vous devez utiliser les broches suivantes :

BME280 ESP8266
SCK (horloge SPI) GPIO 14
ODD (MISO) GPIO 12
IDS (MOSI) GPIO 13
CS (sélection de puce) GPIO 15

Pièces requises

Pour terminer ce tutoriel, vous avez besoin des pièces suivantes :

Vous pouvez utiliser les liens précédents ou accéder directement à MakerAdvisor.com/tools pour trouver toutes les pièces pour vos projets au meilleur prix !

ESP8266 avec BME280 utilisant Arduino IDE pression temperature humidite

Schéma – ESP8266 avec BME280 utilisant I2C

Nous allons utiliser la communication I2C avec le module de capteur BME280. Pour cela, câblez le capteur à l’ESP8266 SDA et SCL broches, comme indiqué dans le diagramme schématique suivant.

Schéma de câblage schématique ESP8266 avec BME280 utilisant I2C

Lecture recommandée: Guide de référence de brochage ESP8266

Installation de la bibliothèque BME280

Pour obtenir des lectures du module de capteur BME280, vous devez utiliser le Bibliothèque Adafruit_BME280. Suivez les étapes suivantes pour installer la bibliothèque dans votre IDE Arduino :

Ouvrez votre IDE Arduino et accédez à Esquisser > Inclure la bibliothèque > Gérer les bibliothèques. Le gestionnaire de bibliothèque devrait s’ouvrir.

Rechercher « adafruit bme280 ” dans la zone de recherche et installez la bibliothèque.

Installation de la bibliothèque BME280 dans l'IDE Arduino

Installation de la bibliothèque Adafruit_Sensor

Pour utiliser la bibliothèque BME280, vous devez également installer le Bibliothèque Adafruit_Sensor. Suivez les étapes suivantes pour installer la bibliothèque dans votre IDE Arduino :

Aller à Esquisser > Inclure la bibliothèque > Gérer les bibliothèques et tapez « Capteur unifié Adafruit” dans le champ de recherche. Faites défiler vers le bas pour trouver la bibliothèque et installez-la.

Installation de la bibliothèque Adafruit Unified Sensor Driver

Après avoir installé les bibliothèques, redémarrez votre IDE Arduino.


Lecture de la pression, de la température et de l’humidité

Pour lire la pression, la température et l’humidité, nous utiliserons un exemple de croquis de la bibliothèque.

ESP8266 avec module de capteur BME280 I2C sur Breadboard

Après avoir installé la bibliothèque BME280 et la bibliothèque Adafruit_Sensor, ouvrez l’IDE Arduino et accédez à Déposer > Exemples > Bibliothèque Adafruit BME280 > essai bme280.

/*********
  Complete project details at https://www.raspberryme.com  
*********/

#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

/*#include <SPI.h>
#define BME_SCK 14
#define BME_MISO 12
#define BME_MOSI 13
#define BME_CS 15*/

#define SEALEVELPRESSURE_HPA (1013.25)

Adafruit_BME280 bme; // I2C
//Adafruit_BME280 bme(BME_CS); // hardware SPI
//Adafruit_BME280 bme(BME_CS, BME_MOSI, BME_MISO, BME_SCK); // software SPI

unsigned long delayTime;

void setup() {
  Serial.begin(9600);
  Serial.println(F("BME280 test"));

  bool status;

  // default settings
  // (you can also pass in a Wire library object like &Wire2)
  status = bme.begin(0x76);  
  if (!status) {
    Serial.println("Could not find a valid BME280 sensor, check wiring!");
    while (1);
  }

  Serial.println("-- Default Test --");
  delayTime = 1000;

  Serial.println();
}

void loop() { 
  printValues();
  delay(delayTime);
}

void printValues() {
  Serial.print("Temperature = ");
  Serial.print(bme.readTemperature());
  Serial.println(" *C");
  
  // Convert temperature to Fahrenheit
  /*Serial.print("Temperature = ");
  Serial.print(1.8 * bme.readTemperature() + 32);
  Serial.println(" *F");*/
  
  Serial.print("Pressure = ");
  Serial.print(bme.readPressure() / 100.0F);
  Serial.println(" hPa");

  Serial.print("Approx. Altitude = ");
  Serial.print(bme.readAltitude(SEALEVELPRESSURE_HPA));
  Serial.println(" m");

  Serial.print("Humidity = ");
  Serial.print(bme.readHumidity());
  Serial.println(" %");

  Serial.println();
}

Afficher le code brut

Nous avons apporté quelques modifications au croquis pour le rendre entièrement compatible avec l’ESP8266.

Comment fonctionne le code

Continuez à lire cette section pour savoir comment le code fonctionne ou passez à la section « Démonstration ».

Bibliothèques

Le code commence par inclure les bibliothèques nécessaires : les fil bibliothèque pour utiliser I2C, et la Adafruit_Sensor et Adafruit_BME280 bibliothèques pour s’interfacer avec le capteur BME280.

#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

Communication SPI

Comme nous allons utiliser la communication I2C, les lignes suivantes qui définissent les pins SPI sont commentées :

/*#include <SPI.h>
#define BME_SCK 14
#define BME_MISO 12
#define BME_MOSI 13
#define BME_CS 15*/

Noter: si vous utilisez la communication SPI, utilisez les broches SPI par défaut de l’ESP8266 :

MOSI MISO CLK CS
GPIO 13 GPIO 12 GPIO 14 GPIO 15

Pression au niveau de la mer

Une variable appelée SEALEVELPRESSURE_HPA est créé.

#define SEALEVELPRESSURE_HPA (1013.25)

Cette variable enregistre la pression au niveau de la mer en hectopascal (équivaut à milibar). Cette variable permet d’estimer l’altitude pour une pression donnée en la comparant à la pression au niveau de la mer. Cet exemple utilise la valeur par défaut, mais pour des résultats plus précis, remplacez la valeur par la pression actuelle au niveau de la mer à votre emplacement.

I2C

Cet exemple utilise le protocole de communication I2C par défaut. Comme vous pouvez le voir, il vous suffit de créer un Adafruit_BME280 objet appelé bme.

Adafruit_BME280 bme; // I2C

Pour utiliser SPI, vous devez commenter cette ligne précédente et décommenter l’une des lignes suivantes.

//Adafruit_BME280 bme(BME_CS); // hardware SPI
//Adafruit_BME280 bme(BME_CS, BME_MOSI, BME_MISO, BME_SCK); // software SPI

mettre en place()

Dans le mettre en place()démarrez une communication série :

Serial.begin(9600);

Et initialisez le capteur :

status = bme.begin(0x76); 
if (!status) {
  Serial.println("Could not find a valid BME280 sensor, check wiring!");
  while (1);
}

Nous initialisons le capteur avec le 0x76 adresse. Si vous n’obtenez pas de lectures de capteur, vérifiez l’adresse I2C de votre capteur. Avec le capteur BME280 câblé à votre ESP8266, exécutez ce croquis de scanner I2C pour vérifier l’adresse de votre capteur. Ensuite, modifiez l’adresse si nécessaire.

Valeurs d’impression

Dans le boucler()la printValues() La fonction lit les valeurs du BME280 et imprime les résultats dans le moniteur série.

void loop() { 
  printValues();
  delay(delayTime);
}

La lecture de la température, de l’humidité, de la pression et de l’altitude estimée est aussi simple que d’utiliser les méthodes suivantes sur le bme objet:

  • bme.readTemperature() – lit la température en Celsius;
  • bme.readHumidity() – lit l’humidité absolue;
  • bme.readPressure() – lit la pression en hPa (hectoPascal = millibar) ;
  • bme.readAltitude(SEALEVELPRESSURE_HPA) – estime l’altitude en mètres en fonction de la pression au niveau de la mer.

Manifestation

Téléchargez le code sur votre ESP8266 et ouvrez le moniteur série à un débit en bauds de 9600. Appuyez sur le bouton RST intégré pour exécuter le code. Vous devriez voir les lectures affichées sur le moniteur série.

Impression des lectures de pression, de température et d'humidité BME280 avec ESP32 dans le moniteur série Arduino IDE

Serveur Web ESP8266 avec capteur BME280

Le capteur BME280 mesure la température, l’humidité et la pression. Ainsi, vous pouvez facilement construire une station météo compacte et surveiller les mesures à l’aide d’un serveur Web construit avec l’ESP8266 – c’est ce que nous allons faire dans cette section

Serveur Web ESP8266 avec capteur BME280 dans Arduino IDE

Copiez le code suivant dans votre IDE Arduino. Ne le téléchargez pas encore. Tout d’abord, vous devez inclure votre SSID et votre mot de passe.

/*********
  Rui Santos
  Complete project details at https://www.raspberryme.com  
*********/

// Load Wi-Fi library
#include <ESP8266WiFi.h>
#include <Wire.h>
#include <Adafruit_BME280.h>
#include <Adafruit_Sensor.h>

//uncomment the following lines if you're using SPI
/*#include <SPI.h>
#define BME_SCK 14
#define BME_MISO 12
#define BME_MOSI 13
#define BME_CS 15*/

#define SEALEVELPRESSURE_HPA (1013.25)

Adafruit_BME280 bme; // I2C
//Adafruit_BME280 bme(BME_CS); // hardware SPI
//Adafruit_BME280 bme(BME_CS, BME_MOSI, BME_MISO, BME_SCK); // software SPI

// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

void setup() {
  Serial.begin(115200);
  bool status;

  // default settings
  // (you can also pass in a Wire library object like &Wire2)
  //status = bme.begin();  
  if (!bme.begin(0x76)) {
    Serial.println("Could not find a valid BME280 sensor, check wiring!");
    while (1);
  }

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the table 
            client.println("<style>body { text-align: center; font-family: \"Trebuchet MS\", Arial;}");
            client.println("table { border-collapse: collapse; width:35%; margin-left:auto; margin-right:auto; }");
            client.println("th { padding: 12px; background-color: #0043af; color: white; }");
            client.println("tr { border: 1px solid #ddd; padding: 12px; }");
            client.println("tr:hover { background-color: #bcbcbc; }");
            client.println("td { border: none; padding: 12px; }");
            client.println(".sensor { color:white; font-weight: bold; background-color: #bcbcbc; padding: 1px; }");
            
            // Web Page Heading
            client.println("</style></head><body><h1>ESP8266 with BME280</h1>");
            client.println("<table><tr><th>MEASUREMENT</th><th>VALUE</th></tr>");
            client.println("<tr><td>Temp. Celsius</td><td><span class=\"sensor\">");
            client.println(bme.readTemperature());
            client.println(" *C</span></td></tr>");  
            client.println("<tr><td>Temp. Fahrenheit</td><td><span class=\"sensor\">");
            client.println(1.8 * bme.readTemperature() + 32);
            client.println(" *F</span></td></tr>");       
            client.println("<tr><td>Pressure</td><td><span class=\"sensor\">");
            client.println(bme.readPressure() / 100.0F);
            client.println(" hPa</span></td></tr>");
            client.println("<tr><td>Approx. Altitude</td><td><span class=\"sensor\">");
            client.println(bme.readAltitude(SEALEVELPRESSURE_HPA));
            client.println(" m</span></td></tr>"); 
            client.println("<tr><td>Humidity</td><td><span class=\"sensor\">");
            client.println(bme.readHumidity());
            client.println(" %</span></td></tr>"); 
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Afficher le code brut

Comment fonctionne le code

Continuez à lire cette section pour savoir comment le code fonctionne ou passez à la section « Démonstration ».

Cette esquisse est très similaire à l’esquisse utilisée dans le didacticiel du serveur Web ESP8266. Tout d’abord, vous incluez le ESP8266Wi-Fi bibliothèque et les bibliothèques nécessaires pour lire à partir du capteur BME280.

// Load Wi-Fi library
#include <ESP8266WiFi.h>
#include <Wire.h>
#include <Adafruit_BME280.h>
#include <Adafruit_Sensor.h>

La ligne suivante définit une variable pour enregistrer la pression au niveau de la mer. Pour une estimation plus précise de l’altitude, remplacez la valeur par la pression actuelle au niveau de la mer à votre emplacement.

#define SEALEVELPRESSURE_HPA (1013.25)

Dans la ligne suivante, vous créez un Adafruit_BME280 objet appelé bme qui établit par défaut une communication avec le capteur en utilisant I2C.

Adafruit_BME280 bme; // I2C

Comme mentionné précédemment, vous devez insérer votre ssid et votre mot de passe dans les lignes suivantes à l’intérieur des guillemets doubles.

const char* ssid     = "";
const char* password = "";

Ensuite, vous configurez votre serveur Web sur le port 80.

// Set web server port number to 80
WiFiServer server(80);

La ligne suivante crée une variable pour stocker l’en-tête de la requête HTTP :

String header;

mettre en place()

Dans le mettre en place()nous commençons une communication série à un débit en bauds de 115200 à des fins de débogage.

Serial.begin(115200);

Vous vérifiez que le capteur BME280 a bien été initialisé.

if (!bme.begin(0x76)) {
  Serial.println("Could not find a valid BME280 sensor, check wiring!");
  while (1);

Les lignes suivantes commencent la connexion Wi-Fi avec WiFi.begin(ssid, mot de passe)attendez une connexion réussie et imprimez l’adresse IP ESP dans le moniteur série.

// Connect to Wi-Fi network with SSID and password
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
  delay(500);
  Serial.print(".");
}
// Print local IP address and start web server
Serial.println("");
Serial.println("WiFi connected.");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
server.begin();

boucler()

Dans le boucler(), nous programmons ce qui se passe lorsqu’un nouveau client établit une connexion avec le serveur Web. L’ESP écoute toujours les clients entrants avec cette ligne :

WiFiClient client = server.available(); // Listen for incoming clients

Lorsqu’une demande est reçue d’un client, nous enregistrons les données entrantes. La boucle while qui suit sera exécutée tant que le client restera connecté.

if (client) { // If a new client connects,
  Serial.println("New Client."); // print a message out in the serial port
  String currentLine = ""; // make a String to hold incoming data from the client
  while (client.connected()) { // loop while the client's connected
    if (client.available()) { // if there's bytes to read from the client,
      char c = client.read(); // read a byte, then
      Serial.write(c); // print it out the serial monitor
      header += c;
      if (c == '\n') { // if the byte is a newline character
        // if the current line is blank, you got two newline characters in a row.
        // that's the end of the client HTTP request, so send a response:
        if (currentLine.length() == 0) {
          // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
          // and a content-type so the client knows what's coming, then a blank line:
          client.println("HTTP/1.1 200 OK");
          client.println("Content-type:text/html");
          client.println("Connection: close");
          client.println();

Affichage de la page Web HTML

La prochaine chose que vous devez faire est d’envoyer une réponse au client avec le texte HTML pour créer la page Web.

La page Web est envoyée au client en utilisant cette expression client.println(). Vous devez entrer ce que vous voulez envoyer au client comme argument.

L’extrait de code suivant envoie la page Web pour afficher les lectures du capteur dans un tableau.

client.println("<!DOCTYPE html><html>");
client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
client.println("<link rel=\"icon\" href=\"data:,\">");
// CSS to style the on/off buttons 
// Feel free to change the background-color and font-size attributes to fit your preferences
client.println("<style>body { text-align: center; font-family: \"Trebuchet MS\", Arial;}");
client.println("table { border-collapse: collapse; width:35%; margin-left:auto; margin-right:auto; }");
client.println("th { padding: 12px; background-color: #0043af; color: white; }");
client.println("tr { border: 1px solid #ddd; padding: 12px; }");
client.println("tr:hover { background-color: #bcbcbc; }");
client.println("td { border: none; padding: 12px; }");
client.println(".sensor { color:white; font-weight: bold; background-color: #bcbcbc; padding: 1px; }");
 
// Web Page Heading
client.println("</style></head><body><h1>ESP32 with BME280</h1>");
client.println("<table><tr><th>MEASUREMENT</th><th>VALUE</th></tr>");
client.println("<tr><td>Temp. Celsius</td><td><span class=\"sensor\">");
client.println(bme.readTemperature());
client.println(" *C</span></td></tr>"); 
client.println("<tr><td>Temp. Fahrenheit</td><td><span class=\"sensor\">");
client.println(1.8 * bme.readTemperature() + 32);
client.println(" *F</span></td></tr>"); 
client.println("<tr><td>Pressure</td><td><span class=\"sensor\">");
client.println(bme.readPressure() / 100.0F);
client.println(" hPa</span></td></tr>");
client.println("<tr><td>Approx. Altitude</td><td><span class=\"sensor\">");
client.println(bme.readAltitude(SEALEVELPRESSURE_HPA));
client.println(" m</span></td></tr>"); 
client.println("<tr><td>Humidity</td><td><span class=\"sensor\">");
client.println(bme.readHumidity());
client.println(" %</span></td></tr>"); 
client.println("</body></html>");

Noter: tu peux cliquez ici pour voir la page Web HTML complète.

Affichage des lectures du capteur

Pour afficher les lectures des capteurs sur le tableau, il suffit de les envoyer entre les

et

Mots clés. Par exemple, pour afficher la température :

client.println("<tr><td>Temp. Celsius</td><td><span class=\"sensor\">");
client.println(bme.readTemperature());
client.println(" *C</span></td></tr>");

Noter: la tag est utile pour styliser une partie particulière d’un texte. Dans ce cas, nous utilisons le balise pour inclure la lecture du capteur dans une classe appelée « capteur ». Ceci est utile pour styliser cette partie particulière du texte à l’aide de CSS.

Par défaut, le tableau affiche les relevés de température en degrés Celsius et Fahrenheit. Vous pouvez commenter les trois lignes suivantes, si vous souhaitez afficher la température uniquement en degrés Fahrenheit.

/*client.println("<tr><td>Temp. Celsius</td><td><span class=\"sensor\">");
client.println(bme.readTemperature());
client.println(" *C</span></td></tr>");*/

Fermeture de la connexion

Enfin, lorsque la réponse se termine, nous effaçons le entête variable, et arrêter la connexion avec le client avec client.stop().

// Clear the header variable
header = "";
// Close the connection
client.stop();

Démonstration du serveur Web

Après avoir inséré vos informations d’identification réseau, vous pouvez télécharger le code sur votre carte.

Vérifiez que vous avez sélectionné la bonne carte et le bon port COM, et téléchargez le code sur votre ESP8266. Après le téléchargement, ouvrez le moniteur série à un débit en bauds de 115200 et copiez l’adresse IP ESP8266.

Adresse IP ESP8266 Moniteur série

Ouvrez votre navigateur, collez l’adresse IP et vous devriez voir les dernières lectures du capteur.

Serveur Web BME280 avec démonstration ESP8266

Pour mettre à jour les lectures, il vous suffit de rafraîchir la page Web.

Tu pourrais aussi aimer: ESP8266 avec capteur DHT11 – Serveur Web asynchrone avec mises à jour automatiques

Conclusion

Cet article était un guide détaillé sur la façon d’obtenir des lectures de pression, de température et d’humidité à partir d’un capteur BME280 avec l’ESP8266 à l’aide de l’IDE Arduino et d’afficher les lectures sur un serveur Web.

Maintenant, vous pouvez aller plus loin dans ce projet et afficher les lectures de vos capteurs sur un écran OLED ; créer un enregistreur de données ; enregistrez les lectures dans votre propre base de données ou envoyez les lectures à votre plate-forme domotique à l’aide de MQTT. Voici quelques projets et tutoriels qui pourraient vous aider à mettre en œuvre ces idées :

Apprenez-en plus sur l’ESP8266 avec notre cours : Domotique avec ESP8266

Merci d’avoir lu.

  • AZDelivery BME280 Barometric Temperature Humidity Air Pressure Sensor Module Compatible avec Arduino et Raspberry Pi incluant Un eBook!
    ✅ Si vous recherchez un capteur de température, d'humidité et de pression atmosphérique petit, précis et économe en énergie pour votre SmartHome ou votre projet de construction de maquette, le module de capteur de pression atmosphérique générique BME280 de AZ-Delivery pour Raspberry Pi est le choix parfait pour vous. ✅ AZ-Delivery Generic BME280 Barometric Temperature Air Pressure Sensor Module compatible avec Raspberry Pi a une plage de mesure de pression de 300 à 1100hpa, une plage de mesure de température de -40°C à +85°C et une plage de mesure d'humidité de 0% à 100%. ✅ Le module de capteur AZ-Delivery BME280 pour Raspberry Pi utilise I2C et fonctionne parfaitement avec les microcontrôleurs 3,3 V et 5 V. ✅ Avec leur haute résolution et leur faible consommation d'énergie, ces modules capteurs sont idéaux pour tous les fabricants. ✅ Ce produit inclut un E-Book qui fournit des informations utiles sur la façon de commencer votre projet. Il permet une installation rapide et fait gagner du temps sur le processus de configuration. On y trouve une série d'exemples d'applications, des guides d'installation complets et des bibliothèques.